通达信-佳奕均线V2.0

{指南针系统}

JJJ:=IF(DYNAINFO(8)>0.01,0.01*DYNAINFO(10)/DYNAINFO(8),DYNAINFO(3));

DDD:=(DYNAINFO(5)<0.01 || DYNAINFO(6)<0.01);

JJJT:=IF(DDD,1,(JJJ<(DYNAINFO(5)+0.01) && JJJ>(DYNAINFO(6)-0.01)));

CYC1:=IF(JJJT,0.01*EMA(AMOUNT,P1)/EMA(VOL,P1),EMA((HIGH+LOW+CLOSE)/3,P1));

CYC2:=IF(JJJT,0.01*EMA(AMOUNT,P2)/EMA(VOL,P2),EMA((HIGH+LOW+CLOSE)/3,P2));

CYC3:=IF(JJJT,0.01*EMA(AMOUNT,P3)/EMA(VOL,P3),EMA((HIGH+LOW+CLOSE)/3,P3));

CYC4:=IF(JJJT,DMA(AMOUNT/(100*VOL),100*VOL/FINANCE(7)),EMA((HIGH+LOW+CLOSE)/3,120));

E233:=EMA(C,233);

{NOTEXTCYC1:CYC1,COLORGREEN;}

NOTEXTCYC12:IF(CYC1>REF(CYC1,1),CYC1,DRAWNULL),COLORRED;

{NOTEXTCYC2:CYC2,COLORGREEN;}

NOTEXTCYC22:IF(CYC2>REF(CYC2,1),CYC2,DRAWNULL),COLORRED;

{NOTEXTCYC3:CYC3,COLORGREEN;}

NOTEXTCYC32:IF(CYC3>REF(CYC3,1),CYC3,DRAWNULL),COLORRED;

{NOTEXTCYC4:CYC4,COLORGREEN,LINETHICK2;}

NOTEXTCYC42:IF(CYC4>REF(CYC4,1),CYC4,DRAWNULL),COLORRED,LINETHICK2;

NOTEXTCYC43:IF(HHV(CYC4,13)/LLV(CYC4,13)<1.01,CYC4,DRAWNULL),COLORLIBLUE,LINETHICK2;

{DRAWSL(ISLASTBAR=1,E233,0,55,1),COLORLIGREEN;}

{抛物线赋值}

VAR11:=SAR(4,2,20);

{支撑、压力提示}

抛物线:=STRCAT('转:',CON2STR(VAR11,2));

阻力1:=STRCAT('|',CON2STR(CYC1,2));

阻力2:=STRCAT('-',CON2STR(CYC2,2));

阻力3:=STRCAT('-',CON2STR(CYC3,2));

阻力4:=STRCAT('|主:',CON2STR(CYC4,2));

年线:=STRCAT('|年:',CON2STR(E233,2));

阻力11:=STRCAT(阻力1,阻力2);

阻力22:=STRCAT(阻力3,阻力4);

阻力33:=STRCAT(阻力11,阻力22);

阻力55:=STRCAT('|收:',CON2STR(C,2));

阻力44:=STRCAT(抛物线,阻力55);

阻力66:=STRCAT(阻力44,阻力33);

阻力:=STRCAT(阻力66,年线);

强多头:= C>VAR11 AND C>CYC4 AND C>E233;

弱多头:=C>VAR11 AND ((C>CYC4 AND C<E233) OR (C<CYC4 AND C>E233) OR (C<CYC4 AND C<E233));

空头:=NOT(强多头 OR 弱多头);

DRAWTEXT_FIX(ISLASTBAR=1 AND 强多头 AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7),0.7,0.95,1,阻力),COLORRED;

DRAWTEXT_FIX(ISLASTBAR=1 AND 弱多头 AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7),0.7,0.95,1,阻力),COLORLIRED;

DRAWTEXT_FIX(ISLASTBAR=1 AND 空头 AND    (PERIOD=5 OR PERIOD=6 OR PERIOD=7),0.7,0.95,1,阻力),COLORLIGREEN;

{市场盈亏-20,-5,0,5}

CYC13:=0.01*EMA(AMOUNT,13)/EMA(VOL,13);

CYS1:=(CLOSE-CYC13)/CYC13*100;

市场盈亏:=STRCAT('市场盈亏 | 本:',CON2STR(CYS1,2));

市场盈亏1:=STRCAT(市场盈亏,' | 上:');

市场盈亏11:=STRCAT(市场盈亏1,CON2STR(REF(CYS1,1),2));

市场盈亏2:=STRCAT(市场盈亏11,' | 前:');

市场盈亏22:=STRCAT(市场盈亏2,CON2STR(REF(CYS1,2),2));

DRAWTEXT_FIX(ISLASTBAR=1 AND CYS1<=-20 AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7),0.7,0.87,1,市场盈亏22),COLORRED;

DRAWTEXT_FIX(ISLASTBAR=1 AND (CYS1<=5 AND CYS1>=-5) AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7),0.7,0.87,1,市场盈亏22),COLORLIRED;

DRAWTEXT_FIX(ISLASTBAR=1 AND (CYS1<=-5 AND CYS1>-20) AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7),0.7,0.87,1,市场盈亏22),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR=1 AND CYS1>5 AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7),0.7,0.87,1,市场盈亏22),COLORRED;

{90%筹码}

A:=90+(100-90)/2;

B:=(100-90)/2;

CC:=COST(A);

DD:=COST(B);

集中90:=(CC-DD)/ COST(100)*100;

筹码1:=STRCAT('90%筹码-今:',CON2STR(集中90,2));

筹码2:=STRCAT('-昨:',CON2STR(REF(集中90,1),2));

筹码3:=STRCAT('-前:',CON2STR(REF(集中90,2),2));

筹码4:=STRCAT('-55NIN:',CON2STR(LLV(集中90,55),2));

筹码11:=STRCAT(筹码1,筹码2);

筹码12:=STRCAT(筹码3,筹码4);

筹码:=STRCAT(筹码11,筹码12);

{输出筹码文字显示}

高度集中:=(集中90=LLV(集中90,55));

DRAWTEXT_FIX(ISLASTBAR=1 AND  PERIOD=5 AND 高度集中,0.7,0.79,1,筹码),COLORRED;

DRAWTEXT_FIX(ISLASTBAR=1 AND  PERIOD=5 AND NOT(高度集中),0.7,0.79,1,筹码),COLORLIBLUE;

{竞价相关情况}

SUMV:=SUM(V,0);

竞价量:=REF(SUMV,BARSLAST(TIME2<093000)),NODRAW;

开盘一分钟量:=REF(SUMV,BARSLAST(TIME2<=093100)),NODRAW;

{竞价量}

SUMBUYV:=SUM(BUYVOL,0);

{返回外盘即DYNAINFO(23)}

竞价主买:=REF(SUMBUYV,BARSLAST(TIME2<093000)),NODRAW;

开盘一分主买:=REF(SUMBUYV,BARSLAST(TIME2<=093100)),NODRAW;

{竞价主买,即外盘量}

SUMSELLV:=SUM(SELLVOL,0);

{返回内盘即DYNAINFO(22)}

竞价主卖:=REF(SUMSELLV,BARSLAST(TIME2<093000)),NODRAW;

开盘一分主卖:=REF(SUMSELLV,BARSLAST(TIME2<=093100)),NODRAW;

{竞价主卖,即内盘量}

竞价主买主卖比:=竞价主买/竞价主卖;

DDDDD:=STRCAT(' | 竞价比:',CON2STR(竞价主买主卖比,2));

{左上屏基本情况提示}

AA1:=STRCAT('流通股:',STRCAT(CON2STR((FINANCE(7)/100000000),2),'亿 '));

AA2:=STRCAT('| 流通比:',STRCAT(CON2STR(FINANCE(7) /FINANCE(1)*100 ,2),'% '));

AA3:=STRCAT('市值:',STRCAT(CON2STR(FINANCE(1)*C/100000000 ,2),'亿'));

AA4:=STRCAT('| 市资比:',STRCAT(CON2STR((FINANCE(1)*REF(C,1))/FINANCE(10) ,2),'倍'));

AA5:=STRCAT('| 流动:',STRCAT(CON2STR(FINANCE(11) /FINANCE(15) ,2),'倍'));

AA6:=STRCAT('| ROE:',STRCAT(CON2STR(FINANCE(33) /FINANCE(34)*100 ,2),'%'));

AA7:=STRCAT('主营:',STRCAT(CON2STR((FINANCE(20)/(FINANCE(20)+FINANCE(22)+FINANCE(24)+FINANCE(25))*100) ,2),'%'));

优质:=FINANCE(11) /FINANCE(15)>2 AND FINANCE(20)/(FINANCE(20)+FINANCE(22)+FINANCE(24)+FINANCE(25))>0.75 AND FINANCE(33) /FINANCE(34)>5;

BB1:=STRCAT(AA1,' ');

BB2:=STRCAT(AA2,'');

BB3:=STRCAT(AA3,' ');

BB4:=STRCAT(AA4,'');

BB5:=STRCAT(AA5,' ');

BB6:=STRCAT(AA6,'');

CC1:=STRCAT(BB1,BB2);

CC2:=STRCAT(BB3,BB4);

CC3:=STRCAT(BB5,BB6);

CC4:=STRCAT(AA7,CC3);

CC5:=STRCAT(CC2,DDDDD);

DRAWTEXT_FIX(1=1  AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7) AND FINANCE(7) /FINANCE(1)*100>98,0.18,0.03,0,CC1),COLORRED;

DRAWTEXT_FIX(1=1  AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7)  AND FINANCE(7) /FINANCE(1)*100<=98,0.18,0.03,0,CC1),COLORLIBLUE;

DRAWTEXT_FIX(1=1  AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7)  AND FINANCE(1)*REF(C,1)/FINANCE(10)<=1.2,0.18,0.12,0,CC5),COLORRED;

DRAWTEXT_FIX(1=1  AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7)  AND FINANCE(1)*REF(C,1)/FINANCE(10)>1.2,0.18,0.12,0,CC5),COLORLIBLUE;

DRAWTEXT_FIX(1=1  AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7)  AND 优质,0.18,0.20,0,CC4),COLORRED;

DRAWTEXT_FIX(1=1  AND  (PERIOD=5 OR PERIOD=6 OR PERIOD=7)  AND NOT(优质),0.18,0.20,0,CC4),COLORLIBLUE;

{成本均线形态}

{转折空头形态}

成1转空头:=CYC1<REF(CYC1,1) AND REF(CYC1,1)>REF(CYC1,2);

成2转空头:=CYC2<REF(CYC2,1) AND REF(CYC2,1)>REF(CYC2,2);

成3转空头:=CYC3<REF(CYC3,1) AND REF(CYC3,1)>REF(CYC3,2);

成4转空头:=CYC4<REF(CYC4,1) AND REF(CYC2,4)>REF(CYC4,2);

成123依次转空头:=(CYC3<REF(CYC3,1) AND REF(CYC3,1)>REF(CYC3,2) AND REF(CYC2,1)<REF(CYC2,2) AND REF(CYC2,2)>REF(CYC2,3) AND REF(CYC1,2)<REF(CYC1,3) AND REF(CYC1,3)>REF(CYC1,4));

成12依次转空头:=CYC2<REF(CYC2,1) AND REF(CYC2,1)>REF(CYC2,2) AND REF(CYC1,1)<REF(CYC1,2) AND REF(CYC1,2)>REF(CYC1,3);

{转折多头形态}

成1转多头:=CYC1>REF(CYC1,1) AND REF(CYC1,1)<REF(CYC1,2);

成2转多头:=CYC2>REF(CYC2,1) AND REF(CYC2,1)<REF(CYC2,2);

成3转多头:=CYC3>REF(CYC3,1) AND REF(CYC3,1)<REF(CYC3,2);

成4转多头:=CYC4>REF(CYC4,1) AND REF(CYC2,4)<REF(CYC4,2);

{空头形态}

成1空头:=CYC1<REF(CYC1,1) AND REF(CYC1,1)<REF(CYC1,2);

成2空头:=CYC2<REF(CYC2,1) AND REF(CYC2,1)<REF(CYC2,2);

成3空头:=CYC3<REF(CYC3,1) AND REF(CYC3,1)<REF(CYC3,2);

成4空头:=CYC4<REF(CYC4,1) AND REF(CYC2,4)<REF(CYC4,2);

成本空头:=成4空头 OR (C<E233);

{多头形态}

成1多头:=CYC1>REF(CYC1,1) AND REF(CYC1,1)>REF(CYC1,2);

成2多头:=CYC2>REF(CYC2,1) AND REF(CYC2,1)>REF(CYC2,2);

成3多头:=CYC3>REF(CYC3,1) AND REF(CYC3,1)>REF(CYC3,2);

成4多头:=CYC4>REF(CYC4,1) AND REF(CYC2,4)>REF(CYC4,2);

{平盘形态}

成4MAX:=HHV(CYC4,5);

成4MIN:=LLV(CYC4,5);

平盘:=((成4MAX/成4MIN)<1.01);

{入场条件}

成1上穿1:=CROSS(CYC1,CYC2) AND CROSS(CYC2,CYC3) AND CROSS(CYC3,CYC4);

成1上穿2:=CROSS(CYC1,CYC2) AND CROSS(CYC1,CYC3) AND CROSS(CYC1,CYC4);

成4上穿1:=CROSS(CYC1,CYC2) AND 成3多头 AND 成4多头;

成4上穿2:=CROSS(REF(CYC1,1),REF(CYC3,1)) AND CROSS(CYC1,CYC2) AND 成4多头;

成4上穿3:=CROSS(REF(CYC1,1),REF(CYC4,1)) AND CROSS(CYC2,CYC4) AND 成3多头 AND 成4转多头;

成4上穿4:=CROSS(REF(CYC1,2),REF(CYC4,2)) AND CROSS(CYC2,CYC4) AND 成3多头 AND 成4多头;

成4上穿5:=CROSS(CYC1,CYC4) AND CROSS(CYC1,CYC3) AND CROSS(REF(CYC1,1),REF(CYC2,1));

成4上穿6:=CROSS(CYC1,CYC4) AND 成2多头 AND 成3多头 AND 成4转多头;

入场:=成1上穿1 OR 成1上穿2  OR 成4上穿1 OR 成4上穿2 OR 成4上穿3 OR 成4上穿4 OR 成4上穿5 OR 成4上穿6;

{离场条件:成本均线中两条均线、三条均线或四条均线同时转折向下离场}

离场1:=成1转空头 AND 成2转空头 AND 成3多头 AND 成4多头;

离场2:=成1转空头 AND 成3转空头 ;

离场3:=成1转空头 AND 成4转空头;

离场4:=成2转空头 AND 成3转空头 AND 成4多头;

离场5:=成2转空头 AND 成4转空头;

离场6:=成3转空头 AND 成4转空头;

离场7:=成1转空头 AND 成2转空头;

离场8:=成1转空头 AND 成2转空头 AND 成4转空头;

离场9:=成1转空头 AND 成3转空头 AND 成4转空头;

离场:=(离场1 OR 离场2 OR 离场3 OR 离场4 OR 离场5 OR 离场6 OR 离场7 OR 离场8 OR 离场9 OR 成123依次转空头 OR 成12依次转空头) AND NOT(成4空头);

DRAWICON(入场,L,5);

DRAWICON(FILTER(离场,13),H,6);